ABAP Samples

>Support and Tips>Tips>ABAP Samples

ABAP Samples

ERP-Scale simplifies the integration of weighing devices with SAP To use RFC HU_GET_RFC_DATA from your own ABAP's, there are two steps. If you have defined packing station profiles in customising (transaction HUPAST_C), then you can use the function module read_packstation to determine the profile based on the hostname of the user's PC Use the RFC call HU_GET_RFC_DATA in conjunction with ERP-Scale to determine the current weight from the serial device

Determine Packing station profile based on hostname of user's PC

FORM read_packstation.

  statics sf_terminal(20).
  DATA: lt_profile TYPE TABLE OF hupast_t.
* Get the Hostname from the PC.
  CALL FUNCTION 'TH_USER_INFO'
    IMPORTING
      terminal = sf_terminal.
* Prerequisite only one profile per PC
  SELECT * FROM hupast_t CLIENT SPECIFIED INTO TABLE lt_profile
        WHERE terminal = sf_terminal AND client = sy-mandt.
  IF NOT sy-subrc IS INITIAL.
    EXIT.
  ENDIF.
  READ TABLE lt_profile TRANSPORTING NO FIELDS INDEX 2.
  IF sy-subrc IS INITIAL.
    EXIT.
  ENDIF.
  READ TABLE lt_profile INTO gs_profile INDEX 1.
* PERFORM set_profile.
ENDFORM.                    "read_packstation

Call to RFC function HU_GET_RFC_DATA

  ls_weight-brgew = '0.000'.
  ls_weight-gewei = space.
  append ls_weight to lt_weight.

  CALL FUNCTION 'HU_GET_RFC_DATA' destination l_rfc_destination
    TABLES
      ET_WEIGHT             = lt_weight
    EXCEPTIONS "<< begin note 205878
      COMMUNICATION_FAILURE = 1  MESSAGE MSG_TEXT
      SYSTEM_FAILURE        = 2  MESSAGE MSG_TEXT.
  .
  if not sy-subrc is initial.
    concatenate text-040 l_rfc_destination msg_text
                   into msg_text separated by space.
    message s001(vl) with msg_text.
  leave to transaction 'ZTESTWEIGH'.
  endif.
  clear ls_weight.
  read table lt_weight into ls_weight index 1.
  if ls_weight-brgew is initial.
    message e203(hudialog) with l_rfc_destination.
  endif.
  catch system-exceptions CONVT_NO_NUMBER = 9 .
    p_weight = ls_weight-brgew.
  endcatch.

Complete example

*&---------------------------------------------------------------------*
*& Report  ZTESTSCALE                                                  *
*&                                                                     *
*&---------------------------------------------------------------------*
*& Author: Pocket Programs 2006                                        *
*& =============================                                       *
*& Example ABAP for use with ERP-Scale see www.pocketprograms.com             *
*&                                                                     *
*& Requires transaction ZTESTWEIGH to be created to run this report    *
*&                                                                     *
*&---------------------------------------------------------------------*

REPORT  ZTESTSCALE                            .


parameter: p_packst like hupast_T-PACKING_STATION default 'ERPSCALE'.
parameter: p_weight(20) memory id ZWEIGHT.

data: gs_profile type hupast_t.


data: lt_weight type table of hum_scale,

      ls_weight type hum_scale,

      MSG_TEXT(120) TYPE C, "Message text 

      L_RFC_DESTINATION LIKE RFCDISPLAY-RFCDEST.

data: l_weight like vekp-brgew.


initialization.

  perform read_packstation.
  p_packst = gs_profile-packing_station.


start-of-selection.

  perform read_profile using p_packst.


* rfc-destination aus Customizing:
  l_rfc_destination = gs_profile-RFC_FOR_SCALE.
  ls_weight-waage = gs_profile-NAME_OF_SCALE.



  if l_rfc_destination is initial.

    message e203(hudialog) with l_rfc_destination.

  endif.


* Function module must be called with at least one
* entry in the table

  ls_weight-brgew = '0.000'.
  ls_weight-gewei = space.
  append ls_weight to lt_weight.

  CALL FUNCTION 'HU_GET_RFC_DATA' destination l_rfc_destination
    TABLES
      ET_WEIGHT             = lt_weight
    EXCEPTIONS "<< begin note 205878
      COMMUNICATION_FAILURE = 1  MESSAGE MSG_TEXT
      SYSTEM_FAILURE        = 2  MESSAGE MSG_TEXT.
  .
  if not sy-subrc is initial.
    concatenate text-040 l_rfc_destination msg_text
                   into msg_text separated by space.
    message s001(vl) with msg_text.
  leave to transaction 'ZTESTWEIGH'.
  endif.
  clear ls_weight.
  read table lt_weight into ls_weight index 1.
  if ls_weight-brgew is initial.
    message e203(hudialog) with l_rfc_destination.
  endif.
  catch system-exceptions CONVT_NO_NUMBER = 9 .
    p_weight = ls_weight-brgew.
  endcatch.
  if sy-subrc = 9.
    message s000(zz) with ls_weight.
  else.
    concatenate p_weight ls_weight-GEWEI into p_weight
    separated by space.
    message s000(zz) with p_weight.
  endif.
  set parameter ID 'ZWEIGHT' field p_weight.
  leave to transaction 'ZTESTWEIGH'.




*&---------------------------------------------------------------------*
*&      Form  READ_PROFILE
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM read_packstation.

  statics sf_terminal(20).
  DATA: lt_profile TYPE TABLE OF hupast_t.
* Get hostname from PC
  CALL FUNCTION 'TH_USER_INFO'
    IMPORTING
      terminal = sf_terminal.
* prerequisite there is only one profile per PC
  SELECT * FROM hupast_t CLIENT SPECIFIED INTO TABLE lt_profile
        WHERE terminal = sf_terminal AND client = sy-mandt.
  IF NOT sy-subrc IS INITIAL.
    EXIT.
  ENDIF.
  READ TABLE lt_profile TRANSPORTING NO FIELDS INDEX 2.
  IF sy-subrc IS INITIAL.
    EXIT.
  ENDIF.
  READ TABLE lt_profile INTO gs_profile INDEX 1.
* PERFORM set_profile.
ENDFORM.                    "read_packstation

*&---------------------------------------------------------------------*
*&      Form  READ_PROFILE
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM read_profile using p_st.

  DATA: lt_profile TYPE TABLE OF hupast_t.
* prerequisite there is only one profile per PC
  SELECT * FROM hupast_t CLIENT SPECIFIED INTO TABLE lt_profile
        WHERE PACKING_STATION = p_st AND client = sy-mandt.
  IF NOT sy-subrc IS INITIAL.
    EXIT.
  ENDIF.
  READ TABLE lt_profile TRANSPORTING NO FIELDS INDEX 2.
  IF sy-subrc IS INITIAL.
    EXIT.
  ENDIF.
  READ TABLE lt_profile INTO gs_profile INDEX 1.
* PERFORM set_profile.
ENDFORM.                    "read_profile

News List